MOLEHAND Solutions - Nagyvállalati megoldások mindenkinek

 
nov. 26

Written by: MOLEHAND
2007. 11. 26. 12:08

Sok új felhasználó hozzáadását célszerű és gyorsabb script használatával végezni.

Mindez lehetséges a dcadd parancs használatával batch-fájlból.

De tisztább megoldás Visual Basic Scriptet használni.

Option Explicit
Const ForReading = 1

Dim objDomain, objUser, fso, tsInputFile, strLine, arrInput
Dim fldUserHomedir, wshShell

'Domain objektum ldap lekerdezessel, ertelemszeruen sorban OU-ktol indulva
Set objDomain = GetObject("
LDAP://ou=Users,ou=domainPartners,dc=local,dc=domain,dc=hu")
Set fso = CreateObject("Scripting.FileSystemObject")

'Feldolgozando fajl
Set tsInputFile = fso.OpenTextFile("C:\Users\agombos\Desktop\FTP\Migration\service_users2.csv", ForReading, False)

'Csv sorainak beolvasa
'Csv formatumba az alabbi esetben:
'"username", "display name","e-mail address","password"
While Not tsInputFile.AtEndOfStream

  strLine = tsInputFile.ReadLine
  'Elvalaszto karakter a ",", igy tordeli a beolvasott sort
  'A sorbol egy arrinput tomb lesz, a sor elsoeleme a tomb elso eleme - arrInput(0)
  arrInput = Split(strLine, ",")
  'Username alapjan az uj userobjektum letrehozasa, es az atrributumok feltoltese
  Set objUser = objDomain.Create("user","cn=" & arrInput(0))
  objUser.Put "sAMAccountName", arrInput(0)
  objUser.Put "userPrincipalName", arrInput(0) & "@local.domain.hu"
  'Attributumok feltoltese a tomb tobbi eleme alapjan
  objUser.Put "description", arrInput(1)
  objUser.Put "displayName", arrInput(1)
  objUser.Put "mail", arrInput(2)
  'A jelszo hozzarendeles elott mentsuk az objektumot az LDAPba
  objUser.SetInfo
 
  'Lekerdezzuk az uj objektumot LDAP-bol, es azon dolgozunk tovabb - itt elmeletileg objUser.GetInfo fuggvenyhivas is eleg kellene hogy legyen
  Set objUser = GetObject("
LDAP://cn=" & arrinput(0) & ",ou=Users,ou=domainPartners,dc=local,dc=domain,dc=hu")
  'Alapbol disabled statuszban jon letre az objektum
  objUser.AccountDisabled = False
  objUser.SetPassword arrInput(3)
  'Mentjuk az "enabled", es jelszovat ellatott user objektumot
  objUser.SetInfo
  'objUser valtozott kinulazzuk
  Set objUser = Nothing
Wend

'Fajl zarasa
tsInputFile.Close

 

Csvt fájlt Excelben fel lehet tölteni adatokkal. Jelszavak generálására a Balázs által linkelt http://www.pctools.com/guides/password/ oldal ideális. Itt Quantityvel meg lehet adni, hogy hány új jelszóra van szükségünk, használható nagy mennyiségű jelszó generálására a pwgen UNIX alkalmazás is.

Tags:

Your name:
Title:
Comment:
Security Code
Enter the code shown above in the box below
Add Comment    Mégsem  
 

Számítsa ki költségeit
  kalkulátorunkkal

tovább    

és nyerje meg
50 000 Ft értékű

ajándékunkat  

Akciós ajánlatunk

 Több szolgáltatót is volt szerencsém kipróbálni. Jelenleg minden projektünk a MOLEHAND-nél van elhelyezve, mert Ők nem csak egy szelet számítógépet adnak, hanem valódi szolgáltatást: Akármibe ütközök számíthatok a gyors és szakszerű reakcióra!